home *** CD-ROM | disk | FTP | other *** search
/ Floppyshop 2 / Floppyshop - 2.zip / Floppyshop - 2.iso / art&graf.ix / art-4641 / spritefx / source / example.s < prev    next >
Text File  |  1994-05-12  |  18KB  |  679 lines
  1. ******************************************************************** 
  2. ********************************************************************
  3. * This is an example programe using files created with SPRITEFX
  4. * and uses routines that are fairly simple so as to be suitable 
  5. * for beginers. For this reason and because of the fact that the
  6. * sprite routine is universal, handling multiple size sprites, 
  7. * the routines have not been optimised for maximum speed. Also
  8. * the routines are set up to use only variable speed sequence
  9. * files with frame numbers going from low to high and X/Y only
  10. * path files. Full save and restore has been implemented on the
  11. * background which is not always nessecary or could be acheived 
  12. * by other, faster methods but as mentioned above this file was 
  13. *created with beginers in mind. More advanced methods and routines
  14. * have been used in the programe in the demo folder, the source
  15. * code for which can be obtained with the registered version of
  16. * SPRITEFX, please read "reg.txt" on disk. For more details on 
  17. * using SPRITEFX files within your own programes read the manule
  18. * in the "docs" folder.    
  19. ******************************************************************** 
  20. ************************ FILE INFORMATION **************************
  21. * For more detailed information on the following files please read
  22. * SPRITEFX.DOC in the MANUAL folder. The ghost sprites where created
  23. * by using the same sprite screen loaded into SPRITEFX then turning
  24. * off planes 1 and 4 and saving as such.
  25. ********************************************************************
  26. * PATH FILES *
  27. *                        _
  28. * 1 WORD      * SPRITEFX INFORMATION         |-HEADER
  29. * 1 LONGWORD    * NUMBER OF X/Y POSITIONS    _|
  30. *                        _
  31. * 1 WORD    * X POSITION             |-DATA     
  32. * 1 WORD    * Y POSITION             _|
  33. *
  34. * PREVIOUS DATA STRUCTURE TO END OF FILE
  35. *
  36. ******************************************************************** 
  37. * 
  38. * SEQUENCE FILES *
  39. *                        _
  40. * 1 LONGWORD    * SPRITEFX INFORMATION         |-HEADER
  41. * 1 WORD    * SPRITEFX INFORMATION         |
  42. * 1 longWORD    * NUMBER OF SEQUENCES        _|
  43. *                        _
  44. * 1 WORD    * FRAME UPDATE SPEED         |-DATA
  45. * 1 WORD    * START FRAME NUMBER         |
  46. * 1 WORD    * END FRAME NUMBER        _|    
  47. *
  48. * PREVIOUS DATA STRUCTURE TO END OF FILE
  49. * FILE IS TERMINATED WITH -1
  50. *
  51. ******************************************************************** 
  52. * 
  53. * SPRITE FILES *
  54. *                        _                                                        
  55. * 1 WORD    * SPRITEFX INFORMATION         |-HEADER
  56. * 1 WORD    * SPRITEFX INFORMATION         |
  57. * 1 LONGWORD    * NUMBER OF SPRITES         |
  58. * 32 WORDS    * SPRITE PALETTE DATA        _|
  59. *                        _ 
  60. * 1 WORD    * MASK DATA             |-DATA
  61. * 1 WORD    * PLANE 1 SPRITE DATA         |
  62. * 1 WORD    * PLANE 2 SPRITE DATA         |
  63. * 1 WORD    * PLANE 3 SPRITE DATA         |
  64. * 1 WORD    * PLANE 4 SPRITE DATA        _|    
  65. *
  66. * PREVIOUS DATA STRUCTURE TO END OF FILE
  67. * 
  68. ******************************************************************** 
  69. * KEYS:- Esc   = rerun animation.
  70. *     Space = quit program. 
  71. ******************************************************************** 
  72.  
  73.  
  74. start    clr.l   -(sp)            supervisor mode on
  75.     move.w  #$20,-(sp)
  76.     trap    #1
  77.     move.l  d0,savereg        old stack address
  78.     
  79.     lea    stack,a7        new stack address 
  80.  
  81. mouseoff
  82.     move #$12,-(sp)            disable mouse reporting
  83.     move #4,-(sp)
  84.     move #3,-(sp)
  85.     trap #13
  86.     addq.l #6,sp
  87.     
  88.     dc.w $A00A            Line-A hide mouse
  89.  
  90. cursor_off
  91.     clr.w    -(sp)
  92.     move.w    #21,-(sp)
  93.     trap    #14
  94.     addq.l    #4,sp
  95.  
  96.         move.w  $484,sav_484
  97.     bclr    #0,$484            no key click
  98.     bclr    #1,$484            no repeat key
  99.  
  100.     move.w  #4,-(sp)        get current resolution        
  101.     trap    #14
  102.     addq.l  #2,sp
  103.     move.w  d0,oldrez        and save it
  104.  
  105.     move.w    #3,-(sp)        get current screen
  106.     trap    #14
  107.     addq.l    #2,sp
  108.     move.l  d0,oldscr        and save it
  109.  
  110.     movem.l $ffff8240.w,d0-d7    save colors...
  111.     movem.l d0-d7,syspal        ..quickly
  112.  
  113.     movem.l spritedata+8,d0-d7    * +8 to skip header
  114.     movem.l d0-d7,$ffff8240.w    new palette
  115.  
  116.     move.l    #screen1,d0        get new physical screen
  117.     add.l    #256,d0
  118.     and.l    #$ffffff00,d0
  119.     move.l    d0,phys            stored address
  120.  
  121.     move.l    #screen2,d0        and new logical screen
  122.     add.l    #256,d0
  123.     and.l    #$ffffff00,d0
  124.     move.l    d0,log            stored address
  125.  
  126. openfile                * load back drop Degas picture
  127.     move.w    #0,-(sp)
  128.     move.l    #picture,-(sp)
  129.     move.w    #$3d,-(sp)
  130.     trap    #1
  131.     addq.l    #8,sp
  132.     tst.w    d0
  133.     bmi    exit
  134.     move.w    d0,handle
  135. loadpalette
  136.     move.l    #palette,-(sp)
  137.     move.l    #34,-(sp)    
  138.     move.w    handle,-(sp)
  139.     move.w    #$3f,-(sp)
  140.     trap    #1
  141.     add.l    #12,sp
  142. loadpicture        
  143.     move.l    #picbuffer,-(sp)
  144.     move.l    #32000,-(sp)    
  145.     move.w    handle,-(sp)
  146.     move.w    #$3f,-(sp)
  147.     trap    #1
  148.     add.l    #12,sp
  149. close    move.w    handle,-(sp)
  150.     move.w    #$3c,-(sp)
  151.     trap    #1
  152.     addq.l    #4,sp
  153.     
  154.     move.w  #0,-(sp)        set low rez
  155.     move.l  phys,-(sp)          phys    
  156.     move.l  log,-(sp)        log
  157.     move.w  #5,-(sp)
  158.     trap    #14
  159.     add.l   #12,sp
  160.  
  161. ****************************************************************** 
  162. * The main programe starts here, if any changes are made or code
  163. * added it may be better to dissable the re-run animation function
  164. * by deleting the check for space being pressed. 
  165. ****************************************************************** 
  166.  
  167. copyscreens            
  168.     lea    picbuffer,a0
  169.     move.l    phys,a1
  170.     move.l    #4000-1,d0
  171. .copy1    move.l    (a0)+,(a1)+    to physical screen    
  172.     move.l    (a0)+,(a1)+    
  173.     dbra    d0,.copy1
  174.     lea    picbuffer,a0
  175.     move.l    log,a1
  176.     move.l    #4000-1,d0
  177. .copy2    move.l    (a0)+,(a1)+    to logical screen    
  178.     move.l    (a0)+,(a1)+    
  179.     dbra    d0,.copy2
  180.  
  181. * create sprite address table
  182.     move.l    spritedata+4,d0        number of sprites in the file
  183.     subq.l    #1,d0
  184.     lea    sprite_table,a0
  185.     lea    spritedata+8+32,a1    first sprite block
  186. .loop    move.l    a1,(a0)+    
  187.     addq.l    #8,a1            skip hight/width/length
  188.     add.l    -4(a1),a1        add length to current position
  189.     dbra    d0,.loop            
  190.  
  191.     clr.l    data_buffer_1a        * clear begining of data buffers
  192.     clr.l    back_buffer_1a
  193.     clr.l    data_buffer_2b
  194.     clr.l    back_buffer_2b
  195.     move.l    #data_buffer_1a,datbuf1    * and store addresses
  196.     move.l    #back_buffer_1a,bakbuf1
  197.     move.l    #data_buffer_2b,datbuf2
  198.     move.l    #back_buffer_2b,bakbuf2
  199.  
  200. * set up variables
  201.  
  202.     clr.b    video            mainly for re-run function
  203.     move.l    #sequence+10,seq_pos
  204.     
  205.     move.l    #path+6,pathpos        
  206.     move.l    seq_pos,a0        position in the sequence file
  207.     move.w    (a0)+,delay        frame update delay
  208.     move.w    delay,countdown
  209.     move.w    (a0)+,frame        sequence start
  210.     move.w    (a0)+,seqend        sequence end
  211. sync
  212.     move.w    #37,-(sp)        xbios vsync
  213.     trap    #14
  214.     addq.l    #2,sp
  215.  
  216.     move.w    #$ff,-(sp)        gemdos rawconio
  217.     move.w    #6,-(sp)
  218.     trap    #1
  219.     addq.l    #4,sp
  220.     
  221.     cmpi.b    #27,d0            Esc ?  if so quit
  222.     beq    exit
  223.     cmpi.b    #' ',d0            Space ? if so re-run
  224.     beq    copyscreens            
  225.  
  226.     cmp.l    #path1end,pathpos    at end of current path?
  227.     blt    update            if not then update possition            
  228.     bra    anim2            if so the do next animation                    
  229. update    move.l    pathpos,a0        currnet position in the path file
  230.     add.l    #4,pathpos        increment position
  231.     move.w    (a0)+,x_pos        get X position
  232.     move.w    (a0),y_pos        get Y position
  233.  
  234.     tst.w    countdown        end of delay?
  235.     bpl    .ok2            no then continue
  236.     addq.w    #1,frame        yes so increment frame number
  237.     move.w    seqend,d0        last frame number in the sequence
  238.     cmp.w    frame,d0        last frame in the sequence?
  239.     blt    .nxtseq            yes so reset variables
  240.     move.w    delay,countdown        no so just reset frame delay                            
  241.     bra    .ok2            and continue    
  242. .nxtseq    add.l    #6,seq_pos        get next sequence    
  243.     move.l    seq_pos,a0        position in the sequence file
  244.     tst.w    (a0)            at end of sequence file?
  245.     bpl    .ok            if no then continue
  246.     bra    anim2            if yes then go to animation 2
  247. .ok    move.l    seq_pos,a0        position in the sequence file
  248.     move.w    (a0)+,delay        frame update delay
  249.     move.w    delay,countdown        and reset delay couter        
  250.     move.w    (a0)+,frame        sequence start
  251.     move.w    (a0)+,seqend        sequence end
  252. .ok2    subq.w    #1,countdown        decrement delay counter
  253.  
  254.     move.w    frame,d0        current frame number
  255.     asl.w    #2,d0            multiply by 4
  256.     lea    sprite_table,a0        sprite addresses
  257.     move.l    0(a0,d0.w),a0        correct sprite block
  258.     move.w    (a0)+,hight    
  259.     move.w    (a0)+,width
  260.     addq.l    #4,a0            skip length    
  261.     move.l    a0,sprite        store address of sprite
  262.     bsr    sprite_routine        
  263.  
  264.     bsr    swapscreens
  265.     bra    sync
  266.  
  267. anim2    
  268. * create new sprite address table
  269.     move.l    ghostdata+4,d0        number of sprites in the file
  270.     subq.l    #1,d0
  271.     lea    sprite_table,a0
  272.     lea    ghostdata+8+32,a1    first sprite block
  273. .loop    move.l    a1,(a0)+    
  274.     addq.l    #8,a1            skip hight/width/length
  275.     add.l    -4(a1),a1        add length to current position
  276.     dbra    d0,.loop            
  277.  
  278.     clr.l    data_buffer_1a        
  279.     clr.l    back_buffer_1a
  280.     clr.l    data_buffer_2b
  281.     clr.l    back_buffer_2b
  282.  
  283.     move.l    #path2+6,pathpos    
  284.  
  285.     move.l    #sequence2+10,seq_pos
  286.     move.l    seq_pos,a0        position in the sequence file
  287.     move.w    (a0)+,delay        frame update delay
  288.     move.w    delay,countdown
  289.     move.w    (a0)+,frame        sequence start
  290.     move.w    (a0)+,seqend        sequence end
  291.  
  292.     clr.b    video
  293. sync2
  294.     move.w    #37,-(sp)
  295.     trap    #14
  296.     addq.l    #2,sp
  297.  
  298.     move.w    #$ff,-(sp)
  299.     move.w    #6,-(sp)
  300.     trap    #1
  301.     addq.l    #4,sp
  302.     
  303.     cmpi.b    #27,d0        Esc ?  if so quit
  304.     beq    exit
  305.     cmpi.b    #' ',d0
  306.     beq    copyscreens            
  307.             
  308.     cmp.l    #path2end,pathpos
  309.     blt    update2
  310.     bra    anim3        
  311. update2    move.l    pathpos,a0
  312.     add.l    #4,pathpos
  313.     move.w    (a0)+,x_pos
  314.     move.w    (a0),y_pos
  315.  
  316.     tst.w    countdown        end of delay?
  317.     bpl    .ok2
  318.     addq.w    #1,frame        yes so increment frame number
  319.     move.w    seqend,d0
  320.     cmp.w    frame,d0        last frame in the sequence?
  321.     blt    .nxtseq            yes so reset variables
  322.     move.w    delay,countdown        no so just reset frame delay                            
  323.     bra    .ok2    
  324. .nxtseq    add.l    #6,seq_pos        get next sequence    
  325.     move.l    seq_pos,a0        position in the sequence file
  326.     move.w    (a0)+,delay        frame update delay
  327.     move.w    delay,countdown        
  328.     move.w    (a0)+,frame        sequence start
  329.     move.w    (a0)+,seqend        sequence end
  330.     bra    anim3            go to animation 3
  331. .ok2    subq.w    #1,countdown    
  332.  
  333.     move.w    frame,d0
  334.     asl.w    #2,d0
  335.     lea    sprite_table,a0
  336.     move.l    0(a0,d0.w),a0    correct sprite block
  337.     move.w    (a0)+,hight    
  338.     move.w    (a0)+,width
  339.     addq.l    #4,a0        skip length    
  340.     move.l    a0,sprite
  341.     bsr    sprite_routine
  342.  
  343.     bsr    swapscreens
  344.     bra    sync2
  345.  
  346. anim3
  347. sync3
  348.     move.w    #37,-(sp)
  349.     trap    #14
  350.     addq.l    #2,sp
  351.  
  352.     move.w    #$ff,-(sp)
  353.     move.w    #6,-(sp)
  354.     trap    #1
  355.     addq.l    #4,sp
  356.     
  357.     cmpi.b    #27,d0        Esc ?  if so quit
  358.     beq    exit
  359.     cmpi.b    #' ',d0
  360.     beq    copyscreens            
  361.             
  362.     add.w    #1,x_pos
  363.     cmp.w    #319,x_pos
  364.     ble    .y
  365.     clr.w    x_pos
  366. .y    move.w    #142,y_pos
  367.  
  368.     tst.w    countdown        end of delay?
  369.     bpl    .ok2
  370.     addq.w    #1,frame        yes so increment frame number
  371.     move.w    seqend,d0
  372.     cmp.w    frame,d0        last frame in the sequence?
  373.     blt    .nxtseq            yes so reset variables
  374.     move.w    delay,countdown        no so just reset frame delay                            
  375.     bra    .ok2    
  376. .nxtseq    add.l    #6,seq_pos        get next sequence    
  377.     move.l    seq_pos,a0
  378.     tst.w    (a0)            at end of sequence file?
  379.     bpl    .ok            if no then continue
  380.     move.l    #sequence2+16,seq_pos    skip header and first sequence
  381. .ok    move.l    seq_pos,a0        position in the sequence file
  382.     move.w    (a0)+,delay        frame update delay
  383.     move.w    delay,countdown        
  384.     move.w    (a0)+,frame        sequence start
  385.     move.w    (a0)+,seqend        sequence end
  386. .ok2    subq.w    #1,countdown    
  387.  
  388.     move.w    frame,d0
  389.     asl.w    #2,d0
  390.     lea    sprite_table,a0
  391.     move.l    0(a0,d0.w),a0    correct sprite block
  392.     move.w    (a0)+,hight    
  393.     move.w    (a0)+,width
  394.     addq.l    #4,a0        skip length    
  395.     move.l    a0,sprite
  396.     bsr    sprite_routine
  397.  
  398.     bsr    swapscreens
  399.     bra    sync3
  400.  
  401.  
  402. exit
  403.         move.w  sav_484,$484
  404. ;    bset    #0,$484
  405. ;    bset    #1,$484
  406.     
  407.          movem.l syspal,d0-d7    old colors back
  408.     movem.l d0-d7,$ffff8240.w
  409.  
  410.     move.w  oldrez,-(sp)    old resolution back
  411.     move.l  oldscr,-(sp)
  412.     move.l  oldscr,-(sp)
  413.     move.w  #5,-(sp)
  414.     trap    #14
  415.     add.l   #12,sp
  416.  
  417. mouseon    
  418.     move #8,-(sp)            enable mouse reporting
  419.     move #4,-(sp)
  420.     move #3,-(sp)
  421.     trap #13
  422.     addq.l #6,sp
  423.     dc.w $A009            Line-A show mouse
  424. cursor_on
  425.     move.w    #1,-(sp)
  426.     move.w    #21,-(sp)
  427.     trap    #14
  428.     addq.l    #4,sp
  429.  
  430.     move.l  savereg,-(sp)
  431.     move.w  #$20,-(sp)
  432.     trap    #1
  433.     addq.l  #6,sp
  434.  
  435.     clr.w   -(sp)
  436.     trap    #1
  437.  
  438. ***************************
  439. waitkey
  440.     move.w    #7,-(sp)
  441.     trap    #1
  442.     addq.l    #2,sp
  443.     rts
  444. ***************************
  445. swapscreens
  446.     btst    #0,video
  447.     beq    set_1    
  448. set    
  449.     move.w    #-1,-(sp)
  450.     move.l    log,-(sp)
  451.     move.l    phys,-(sp)
  452.     move.w    #5,-(sp)
  453.     trap    #14
  454.     lea    12(sp),sp
  455.     bchg    #0,video
  456.     rts
  457. set_1
  458.     move.w    #-1,-(sp)
  459.     move.l    phys,-(sp)
  460.     move.l    log,-(sp)
  461.     move.w    #5,-(sp)
  462.     trap    #14
  463.     lea    12(sp),sp
  464.     bchg    #0,video
  465.     rts
  466.  
  467. ******************************************
  468. * UNIVERSAL SPRITE ROUTINE. 
  469. * HANDLES MULTIPLE SIZE SPRITES 
  470. * WITH CLIPPING ON THE LOWER BORDER.
  471. * MINIMUM SIZE 1 PIXEL HIGH BY 16 WIDE.
  472. * WIDTH MUST BE A MULTIPLE OF 16.
  473. ******************************************
  474. dummy    dc.b    0    not used
  475. video    dc.b    0    screen toggle flag
  476. log    dc.l    0    logical screen address
  477. phys    dc.l    0    physical screen address
  478. x_pos    dc.w    0    absolute X screen position 0-319
  479. y_pos    dc.w    0    absolute Y screen position 0-199
  480. hight    dc.w    0    sprite hight    
  481. width    dc.w    0    sprite width
  482. sprite    dc.l    0    sprite data address
  483. datbuf1    dc.l    0    buffer 1. Used by sprite routine
  484. bakbuf1    dc.l    0    address    of background restore buffer 1
  485. datbuf2    dc.l    0    buffer 2. Used by sprite routine    
  486. bakbuf2    dc.l    0    address of background restore buffer 2
  487. sprite_routine
  488. * putback *
  489.     btst    #0,video
  490.     bne    res2
  491. res1    move.l    datbuf1,a2
  492.     move.l    bakbuf1,a1
  493.     bra    dores
  494. res2    move.l    datbuf2,a2
  495.     move.l    bakbuf2,a1
  496. dores
  497.     tst.l    (a2)
  498.     beq    ex_put
  499.     move.l    (a2)+,a0
  500.     move.l    (a2)+,d7
  501.     move.l    (a2),d4    
  502.     asr.w    #3,d4        divide by 8 
  503. putloop
  504.     move.l    d4,d5    
  505. put    
  506.     move.l    (a1)+,(a0)+
  507.     move.l    (a1)+,(a0)+
  508.     dbra    d5,put        
  509.     lea    160-8(a0),a0
  510.     sub.l    (a2),a0
  511.     dbra    d7,putloop        
  512. ex_put        
  513. * getback *    
  514.     btst    #0,video
  515.     bne    gbuff2
  516. gbuff1    move.l    datbuf1,a2
  517.     move.l    bakbuf1,a0
  518.     move.l    phys,a1
  519.     bra    doget
  520. gbuff2    move.l    datbuf2,a2
  521.     move.l    bakbuf2,a0 
  522.     move.l    log,a1
  523. doget    
  524.     move.w    x_pos,d0
  525.     move.w    y_pos,d1
  526.     mulu.w    #160,d1
  527.  
  528.     lea    0(a1,d1.w),a1    draw on this line
  529.     moveq    #0,d6
  530.     move.w    d0,d6        save X possition
  531.     lsr.w    #1,d0        divide by 2
  532.     and.w    #$fff8,d0    bring to lower 16 boundry
  533.     lea    0(a1,d0.w),a1    correct screen position 
  534.     move.l    a1,(a2)+    save address for restore
  535.     and.w    #$000f,d6    get shift amount in lower 4 bits (0-15)
  536.     moveq.l    #0,d7
  537.     move.w    hight,d7
  538.     move.w    #199,d5        hight of screen
  539.     sub.w    d7,d5        subtract sprite hight from screen hight        
  540.     cmp    y_pos,d5    is its full hight on screen 
  541.     bhi    .noclip        if so don't clip hight.If not...
  542.     move.l    #199,d7        ...find how much is still on screen
  543.     sub.w    y_pos,d7    move it to loop counter
  544. .noclip    
  545.     subq.l    #1,d7
  546.     move.l    d7,(a2)+    to restor counter
  547.     moveq.l    #0,d4
  548.     move.w    width,d4
  549.     asr.w    d4        divide by 8
  550.     move.l    d4,(a2)        to restor counter
  551.     asr.w    #3,d4        divide by 8 
  552. hightloop
  553.     move.l    d4,d5
  554. widthloop
  555.     move.l    (a1)+,(a0)+        
  556.     move.l    (a1)+,(a0)+
  557.     dbra    d5,widthloop    
  558.     lea    160-8(a1),a1
  559.     sub.l    (a2),a1
  560.     dbra    d7,hightloop        
  561. * putsprite *
  562.     btst    #0,video
  563.     bne    pbuff2
  564. pbuff1    move.l    datbuf1,a2
  565.     bra    doput
  566. pbuff2    move.l    datbuf2,a2
  567. doput    
  568.     move.l    sprite,a0    sprite data address    
  569.     move.l    (a2)+,a1    screen address
  570.     move.l    (a2)+,d7    line loop counter
  571. sprite_draw
  572.     move.l    (a2),d5    width loop counter
  573.     asr.w    #3,d5        divide by 8 
  574.     subq.l    #1,d5
  575. spritedraw    
  576.     moveq    #-1,d0
  577.     moveq    #0,d1
  578.     moveq    #0,d2
  579.     moveq    #0,d3
  580.     moveq    #0,d4
  581.     move.w    (a0)+,d0    * mask
  582.     move.w    (a0)+,d1    * plane 1
  583.     move.w    (a0)+,d2    * plane 2
  584.     move.w    (a0)+,d3    * plane 3
  585.     move.w    (a0)+,d4    * plane 4
  586.     ror.l    d6,d0        * shift mask and planes into place
  587.     ror.l    d6,d1
  588.     ror.l    d6,d2
  589.     ror.l    d6,d3
  590.     ror.l    d6,d4
  591.     and.w    d0,(a1)        * lay down the mask and data
  592.     or.w    d1,(a1)+
  593.     and.w    d0,(a1)
  594.     or.w    d2,(a1)+
  595.     and.w    d0,(a1)
  596.     or.w    d3,(a1)+
  597.     and.w    d0,(a1)
  598.     or.w    d4,(a1)+
  599.     swap    d0
  600.     swap    d1
  601.     swap    d2
  602.     swap    d3
  603.     swap    d4
  604.     and.w    d0,(a1)    
  605.     or.w    d1,(a1)+
  606.     and.w    d0,(a1)    
  607.     or.w    d2,(a1)+
  608.     and.w    d0,(a1)    
  609.     or.w    d3,(a1)+
  610.     and.w    d0,(a1)    
  611.     or.w    d4,(a1)+
  612.     lea    -8(a1),a1
  613.     dbra    d5,spritedraw    
  614.     lea    160(a1),a1
  615.     sub.l    (a2),a1    
  616.     dbra    d7,sprite_draw
  617.     rts    
  618.  
  619. oldrez    dc.w    0        * old system resolution
  620. oldscr    dc.l    0        * old system screen address
  621. savereg    dc.l    0        * old stack address        
  622. sav_484    dc.w    0        * saved system vaiable (key click/repeat)
  623. handle    dc.w    0        * file handle
  624. pathpos    dc.l    path+6        * +10 to skip header    
  625. seq_pos    dc.l    sequence+10    * +10 to skip header    
  626. delay    dc.w    0        * frame delay store
  627. countdown            * frame delay countdown
  628.     dc.w    0        * delay countdown
  629. frame    dc.w    0        * current frame number in the sequence 
  630. seqend    dc.w    0        * last frame number in the sequence    
  631. picture    dc.b    'a:\spritefx\source\backdrop.pi1',0
  632. ***************************************************
  633. ***************************************************
  634. * Following binary files included at assembly time.
  635. * Alternatively, ascii versions of these files can 
  636. * be combined with the source code. These files are
  637. * also on disk but remember to change the routines
  638. * to suit these files eg. #sequence+10 to #sequence
  639. * because of the absence of header data.  
  640. ***************************************************
  641. ***************************************************
  642. spritedata
  643.     incbin    a:\spritefx\source\sprites.spr
  644. ghostdata
  645.     incbin    a:\spritefx\source\ghost.spr
  646. sequence
  647.     incbin    a:\spritefx\source\sprites.seq
  648. sequence2
  649.     incbin    a:\spritefx\source\ghost.seq
  650. path    incbin    a:\spritefx\source\sprites.plt
  651. path1end
  652. path2    incbin    a:\spritefx\source\ghost.plt
  653. path2end
  654. ***************************************************
  655. ***************************************************
  656.  
  657.     section bss
  658. syspal    ds.b    32
  659. palette    ds.b    34
  660. data_buffer_1a
  661.     ds.l    4    screen 1 data
  662. data_buffer_2b
  663.     ds.l    4    screen 2 data
  664. back_buffer_1a
  665.     ds.b    256*16    screen 1 background save buffer
  666. back_buffer_2b
  667.     ds.b    256*16    screen 2 background save buffer
  668.  
  669. sprite_table        * Table of sprite addresses
  670.     ds.l    16    * Number of sprites. Adjust as nessecary
  671. picbuffer
  672.     ds.b    32000    
  673. screen1    ds.b    32000+256
  674. screen2    ds.b    32000+256
  675.     even
  676. **********************************
  677.     ds.w    512
  678. stack    ds.l    0
  679.